Uzaktan yazıcı yönetimi röle kullanımı

17 Aralık 2020
uzaktan röle kullanımı

Uzun zamandır yazı ekleyemiyor idim aslında yaptığım işlere devam ediyorum az da olsa ama paylaşım yapacak vaktim olmuyor. Şu aralar büyük yazıcı yapmakla uğraşıyorum bu sırada hali hazırda olan diğer yazıcım için uzaktan erişim ihtiyacım oldu. Uzaktan yazıcı yönetimi. Yazıcıyı kapatmak gibi bende buna yönelik bir şeyler yaptım belki birilerine lazım olur diye paylaşıyorum.

Uzaktan yazıcı yönetimi

Kısaca ne yaptığımı anlatarak başlıyayım. İnternet üzerinden oluşturduğumuz sayfa ile iki adet röleyi açıp kapatma işlemi yapıyoruz. Biri rutinde açıkken diğeri kapalı olarak ayarlı. Birinde yazıcı bağlı diğerine 220v lamba. Gerektiğinde uzaktan bağlandığımda aydınlatıp kamera ile izlemek için.

Görseller ile daha iyi anlaşılacaktır diye düşünüyorum.

Malzemeler işe başlayalım:

  • Nodemcu,
  • 2 adet röle,
  • 2 adet sıva üstü priz,
  • 220v 5v düşüren trafo,
  • Kablo ve jumper kablolar.

 

 

Kutu içerisi biraz karışık oldu çok düzenleyecek  vaktim yoktu. Şimdilik düzgün çalışıyor kodlamaya geçelim.

Uzaktan yazıcı yönetimi.

// Load Wi-Fi library
#include <ESP8266WiFi.h>

// Set your Static IP address
IPAddress local_IP(192, 168, 0, 30);
// Set your Gateway IP address
IPAddress gateway(192, 168, 0, 1);

IPAddress subnet(255, 255, 255, 0);
IPAddress primaryDNS(8, 8, 8, 8);   //optional
IPAddress secondaryDNS(8, 8, 4, 4); //optional

// Replace with your network credentials
const char* ssid     = "Akyol2";
const char* password = "*********";

// Set web server port number to 80
WiFiServer server(80);

// Variable to store the HTTP request
String header;

// Auxiliar variables to store the current output state
String output5State = "off";
String output4State = "off";

// Assign output variables to GPIO pins
const int output5 = 5;
const int output4 = 4;

// Current time
unsigned long currentTime = millis();
// Previous time
unsigned long previousTime = 0; 
// Define timeout time in milliseconds (example: 2000ms = 2s)
const long timeoutTime = 2000;

void setup() {
  Serial.begin(115200);
  // Initialize the output variables as outputs
  pinMode(output5, OUTPUT);
  pinMode(output4, OUTPUT);
  // Set outputs to LOW
  digitalWrite(output5, HIGH);
  digitalWrite(output4, LOW);

  // Connect to Wi-Fi network with SSID and password
  Serial.print("Connecting to ");
  Serial.println(ssid);
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }

  // Configures static IP address
  if (!WiFi.config(local_IP, gateway, subnet, primaryDNS, secondaryDNS)) {
    Serial.println("STA Failed to configure");
  }
  // Print local IP address and start web server
  Serial.println("");
  Serial.println("WiFi connected.");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());
  server.begin();
}

void loop(){
  WiFiClient client = server.available();   // Listen for incoming clients

  if (client) {                             // If a new client connects,
    Serial.println("New Client.");          // print a message out in the serial port
    String currentLine = "";                // make a String to hold incoming data from the client
    currentTime = millis();
    previousTime = currentTime;
    while (client.connected() && currentTime - previousTime <= timeoutTime) { // loop while the client's connected
      currentTime = millis();         
      if (client.available()) {             // if there's bytes to read from the client,
        char c = client.read();             // read a byte, then
        Serial.write(c);                    // print it out the serial monitor
        header += c;
        if (c == '\n') {                    // if the byte is a newline character
          // if the current line is blank, you got two newline characters in a row.
          // that's the end of the client HTTP request, so send a response:
          if (currentLine.length() == 0) {
            // HTTP headers always start with a response code (e.g. HTTP/1.1 200 OK)
            // and a content-type so the client knows what's coming, then a blank line:
            client.println("HTTP/1.1 200 OK");
            client.println("Content-type:text/html");
            client.println("Connection: close");
            client.println();
            
            // turns the GPIOs on and off
            if (header.indexOf("GET /5/on") >= 0) {
              Serial.println("GPIO 5 on");
              output5State = "on";
              digitalWrite(output5, LOW);
            } else if (header.indexOf("GET /5/off") >= 0) {
              Serial.println("GPIO 5 off");
              output5State = "off";
              digitalWrite(output5, HIGH);
            } else if (header.indexOf("GET /4/on") >= 0) {
              Serial.println("GPIO 4 on");
              output4State = "on";
              digitalWrite(output4, HIGH);
            } else if (header.indexOf("GET /4/off") >= 0) {
              Serial.println("GPIO 4 off");
              output4State = "off";
              digitalWrite(output4, LOW);
            }
            
            // Display the HTML web page
            client.println("<!DOCTYPE html><html>");
            client.println("<head><meta name=\"viewport\" content=\"width=device-width, initial-scale=1\">");
            client.println("<link rel=\"icon\" href=\"data:,\">");
            // CSS to style the on/off buttons 
            // Feel free to change the background-color and font-size attributes to fit your preferences
            client.println("<style>html { font-family: Helvetica; display: inline-block; margin: 0px auto; text-align: center;}");
            client.println(".button { background-color: #195B6A; border: none; color: white; padding: 16px 40px;");
            client.println("text-decoration: none; font-size: 30px; margin: 2px; cursor: pointer;}");
            client.println(".button2 {background-color: #77878A;}</style></head>");
            
            // Web Page Heading
            client.println("<body><h1><a href='http://192.168.0.30'>YAZICI KONTROL UNITESI - Web Server</a></h1>");
            
            // Display current state, and ON/OFF buttons for GPIO 5  
            client.println("<p>YAZICI DURUMU:</p>");
            // If the output5State is off, it displays the ON button       
            if (output5State=="off") {
              client.println("<p>Yazici acik</p>");
              client.println("<p><a href=\"/5/on\"><button class=\"button\">KAPAT</button></a></p>");
              client.println("<hr>");
            } else {
              client.println("<p>Yazici kapali</p>");
              client.println("<p><a href=\"/5/off\"><button class=\"button button2\">AC</button></a></p>");
              client.println("<hr>");
            } 
               
            // Display current state, and ON/OFF buttons for GPIO 4  
            client.println("<p>LAMBA - DURUM " + output4State + "</p>");
            // If the output4State is off, it displays the ON button       
            if (output4State=="off") {
              client.println("<p>Lamba kapali</p>");
              client.println("<p><a href=\"/4/on\"><button class=\"button\">AC</button></a></p>");
            } else {
              client.println("<p>Lamba acik</p>");
              client.println("<p><a href=\"/4/off\"><button class=\"button button2\">KAPAT</button></a></p>");
            }
            client.println("<hr>");
            client.println("www.orcunakyol.com.tr");
            client.println("<hr>");
            client.println("</body></html>");
            
            // The HTTP response ends with another blank line
            client.println();
            // Break out of the while loop
            break;
          } else { // if you got a newline, then clear currentLine
            currentLine = "";
          }
        } else if (c != '\r') {  // if you got anything else but a carriage return character,
          currentLine += c;      // add it to the end of the currentLine
        }
      }
    }
    // Clear the header variable
    header = "";
    // Close the connection
    client.stop();
    Serial.println("Client disconnected.");
    Serial.println("");
  }
}

Kod içerisnde ben nodemcuya sabit ip verdim. Her açıldığında o ip almaya çalışacak böylece sabit ip erişebilicez.

Sorunuz olursa ben buradayım 😉

About Orçun AKYOL

Moslow'un İhtiyaçlar piramidinin kendini gerçekleştirme basamağı için girişimlerde olan, Sağlıkçı olup, Bilgisayar Öğretmenliği okuyan bir eğitim neferi 😉
Hemen Paylaş..
Facebook
Twitter

Yorum Yapılmamış

Bir cevap yazın

E-posta hesabınız yayımlanmayacak. Gerekli alanlar * ile işaretlenmişlerdir

The maximum upload file size: 5 MB. You can upload: image. Links to YouTube, Facebook, Twitter and other services inserted in the comment text will be automatically embedded. Drop file here