Kombi Termostat Yapımı

Daha önce kombi için kablosuz kombi termostat yapımı paylaşmıştım. Onu biraz daha zenginleştirerek gözede hitap etsin diye birkaç düzenleme ile yeni bir termostat yaptım. Açıkçası potansiyometrenin dengesiz çalışması beni sinir ediyordu o yüzden buton ile yapmaya karar verdim. Detaylar konu devamında..

Kombi Termostat Yapımı

Daha önce yapmış olduğum kombi termostatına buradan ulaşabilirsiniz.Aslında çok daha güzel fikirlerim vardı termostat için uzaktan yönetme vs gibi ama malum evde büyüklerimiz olduğu için teknolojiyi son anlamda kullanamıyoruz. Bu nedenle butonlu basit bir kullanım sağlamak için bu versiyonu gerçekleştirdim. 3 boyutlu yazıcı aldığım için bu konuda çok faydası oldu diyebilirim. Uğraşmadan hazır olarak kutuya malzemeleri kolayca yerleştirebiliyoruz.

Malzemelere ve kodlamalara geçmeden önce görsel olarak ne yapmışız bir bakalım.

Önceki termostat adaptör ya da 9v pil ile çalışmak zorundaydı. Lcd ekranlı modellerde 9v pil çok dayanmıyor bu yüzden bende direk 220v bağlayabileceğim bir termostat planladım. Yani ister prizden kablo çekin sabitleyin isterseniz fiş yapın direkt prize bağlayın. Bu projede teyp fişi ile tak çıkar şeklinde olacak ve 220 voltu içindeki mini devreyle 5 volta düşürecek şekilde yaptım.

5 volta düşüren mini devre;

Şimdi malzemelere geçelim:

1. 220v to 5v devre
2. teyp kablosu
3. teyp giriş soket
4. plastik proje kutusu
5. arduino pro mini
6. ısı nem ölçer sensör
7. 10k mini potansiyometre
8. 2 adet push buton

Bağlantı şemaları

Verici:

 

 

Alıcı:

 

Pin Bağlantıları:

Verici:

Arduino pro mini

2 – buton

3 – verici data pinine

4 –  buton

5 – dht11 sıcaklık nem sensörü data pinine

7 – lcd ekran 4.pine

8 – lcd ekran 6

9 – lcd ekran 11

10 – lcd ekran 12

11 – lcd ekran 13

12 – lcd ekran 14

2 adet potansiyometre kullanıyorum 10k 1k bunlardan 10k olanı ekranı ayarlamak için orta bacağını lcd ekranın 3.pinine

diğerini ise ekran ışık şiddetini azaltıp artırmak için orta bacağını 15.pine bağlıyorum. Bağlantı şemasını incelerseniz daha iyi anlayabilirsiniz.

 

Alıcı:

Arduino pro mini

2 – led uzun bacak

3 –  alıcı data pini

4 – röle in pini

 

 

 

Şimdi görsellerle nasıl bağlantılar yapmışım buna bakalım.

 

 

Şimdi termostat nasıl çalışıyor kodlamasına bakalım:

Verici Kodları:

/* 433 mhz kablosuz kombi termostatı yapımı
   Ağustos 2019*/
   
 /* www.orcunakyol.com.tr */
 

#include "DHT.h" //kütüphaneyi içeri alıyoruz
#define DHTPIN 5 //sıcaklığı okuduğumuz data pini
#define DHTTYPE DHT11 // dht hangi verisyon olduğunu yazıyoruz üzerinde yazar
DHT dht(DHTPIN, DHTTYPE);  //dht kısa ismini ve pinini veriyoruz.
int b,c,d;        //  Kullanacağımız sıcaklık nem değişkenler.

#include <LiquidCrystal.h>
LiquidCrystal lcd(7, 8, 9, 10, 11 , 12);

#include <VirtualWire.h> // Bu kartın arduino ile çalışabilmesi için gerekli kütüphane yazı içinde bulabilirsiniz.
char*mesaj; // burada bir char tanımlıyoruz göndereceğimiz mesajı bunun içine yazarak göndereceğiz.
char*ileti;

//buton kısmı

const int buton = 2; // artırma butonu
const int buton_2= 4; //azaltma butonu
int sayac = 15; // sayımızı tutacak değişken 
int butonDurumu = 0; // ilk butonu sıfırlıyoruz basılı olarak görünce 1 olacak
int sondurum = 0; // butonu tekrar sıfırlıcaz ki saymasın bi daha
int butonDurumu_2 = 0; //bunlarda ikinci buton için aynı şeyler
int sondurum_2 = 0;

//buton kısmı bitti.

int ekrana_yazma=25;
int lcd_yazma=14;
 
void setup() {
  
dht.begin(); //dht haberleşmeyi açtık
pinMode(buton,INPUT);
pinMode(buton_2, INPUT);
Serial. begin(9600); 
   vw_set_ptt_inverted(true);
   vw_set_tx_pin(3); // vericideki data yazan pini bağladığımız pin numarası.
   vw_setup(4000);
   ileti="5";
   b=dht.read();   // dht11 kontrol
c=dht.readTemperature(); // sıcaklığı c ye aktardık
d =dht.readHumidity();  // nemi d ye aktardık  
lcd.begin(16, 2); //lcd ekrana yazıyoruz
lcd.setCursor(0, 0);
lcd.print("Oda:");
lcd.print(c);
lcd.print("  Nem: %");
lcd.print(d);
lcd.setCursor(0,1);
lcd.print("istenilen:");
lcd.print(sayac);
}
 
void loop() {

butonDurumu = digitalRead(buton); 
butonDurumu_2 = digitalRead(buton_2); 
if (butonDurumu != sondurum) { 
if (butonDurumu == HIGH) { 
sayac++; 
Serial.println(sayac);
} 
delay(50); 
} 
if (butonDurumu_2 != sondurum_2) { 
if (butonDurumu_2 == HIGH) { 
sayac--; 
Serial.println(sayac); 
} 
delay(50); 
} 
sondurum = butonDurumu;
sondurum_2 = butonDurumu_2;
 
b=dht.read();   // dht11 kontrol
c=dht.readTemperature(); // sıcaklığı c ye aktardık
d =dht.readHumidity();  // nemi d ye aktardık  



  if(ekrana_yazma != c || lcd_yazma!=sayac){
    Serial.println(c);
    lcd.begin(16, 2); //lcd ekrana yazıyoruz
lcd.setCursor(0, 0);
lcd.print("Oda:");
lcd.print(c);
lcd.print("  Nem: %");
lcd.print(d);
lcd.setCursor(0,1);
lcd.print("istenilen:");
lcd.print(sayac);
    ekrana_yazma=c;
    lcd_yazma=sayac;
  }
  
  //Burada istenilen sıcaklık, oda sıcaklığından büyük ise kombi çalışır değilse çalışmaz.
  if (sayac > c) {
    mesaj = "1" ; //kombi çalışma mesajı.
    gonder();
  } 
  else if (sayac < c){
    mesaj="0"; //kombi kapat, kapalı kalmaya devam et.
    gonder();
  }
}


void gonder (){

if (ileti != mesaj){
   Serial.println(mesaj);
   vw_send((uint8_t *)mesaj, strlen(mesaj)); //hazırladığımız mesaj değişkenindeki içeriği butona basılma durumuna göre alıcıya gönderdik.
   vw_wait_tx();
   ileti = mesaj;
   delay(100);
}
}

 

Alıcı Kodları:

/* 433 mhz kablosuz kombi termostatı yapımı
   Ağustos 2019*/
   
 /* www.orcunakyol.com.tr */



#include <VirtualWire.h>  // Bu kartın arduino ile çalışabilmesi için gerekli kütüphane yazı içinde bulabilirsiniz.
char*mesaj;  // // burada bir char tanımlıyoruz alacağımız mesajı bunun içine yazarak göreceğiz.
int led=2; //yanacak olan ledi 2.pine bağlıyoruz.
int kombi=4;
 
void setup() {
pinMode(led,OUTPUT);
pinMode(kombi, OUTPUT);
digitalWrite(kombi, HIGH);
 
    vw_set_ptt_inverted(true);
    vw_set_rx_pin(3); // vericideki data yazan pini bağladığımız pin numarası.
    vw_setup(4000);
    vw_rx_start();
}
 
void loop() {
    uint8_t buf[VW_MAX_MESSAGE_LEN];  // gelen mesajı tanımlıyoruz.
    uint8_t buflen = VW_MAX_MESSAGE_LEN;
    if (vw_get_message(buf, &buflen)) // Eğer gelen mesaj var ise içerisine gir.
    {
         if(buf[0]=='1'){ //mesaj 2 ise ledi yak
         digitalWrite(led,HIGH);
         digitalWrite(kombi, LOW);
         delay(100);
         }
         if(buf[0]=='0'){ //gelen mesaj 5 ise söndür sönük kalmaya devam et.
          digitalWrite(led,LOW); 
          digitalWrite(kombi,HIGH);
          delay(100); 
         }         
   }
    
}

 

Bu video ile çalışma testini izleyebilirsiniz.

İlginize teşekkür eder, sorularınızı ve destek yorumlarınızı beklerim. Sevgiyle kalın..